Contact | Privacy | Datenschutzerklärung | Impressum

Syntax of heitml

heitmlpage::= heitml * .
heitml::= HTMLText
| <? Expr [ Format ] >
| <assign Expr> heitml * </assign>
| <break>
| <def MethodName FormalParameterList > DefinitionModifiers heitml * </def>
| <defbody>
| <defclass ClassName > <inherit ClassName ([,] ClassName)* > heitml * </defclass>
| <defenv MethodName FormalParameterList > DefinitionModifiers heitml * </defenv>
| <dbquery [ VariableName ] > heitml * Section * </dbquery>
| <dbupdate> heitml * </dbupdate>
| <for VariableName = Expr Expr Expr > heitml * [ <forsep> heitml * ] </for>
| <forin VariableName Expr > heitml * [ <forsep> heitml * ] </forin>
| <if Expr > heitml * [ <elsif Expr > heitml * ] * [ <else> heitml * ] </if>
| <include Filename >
| <include name = "Filename" [ / ] >
| <include> heitml * </include>
| <mail ActualParameterList > heitml * </mail>
| <return [Expr] >
| <shell> heitml * </shell>
| < MethodName ActualParameterList > [ heitml * </ MethodName > ]
| < MethodName ActualParameterList />
| <callenv Expr . MethodName ( ActualParameterList ) > heitml * </ callenv>
| <while Expr > heitml * </while>
| <writefile Expr > heitml * </writefile>.
DefinitionModifiers::= [ <inherit ClassName ([,] ClassName)* > ]
[ <defwysiwyg> ]
[ <defhtml> ]
[ <defautoclose> ].
Section::= <dbrow> heitml *
| <dbtop> heitml *
| <dbfoot> heitml *
| <dbempty> heitml *
| <dbhead> heitml *
| <dbbody> heitml *
| <dbcolumn> heitml *
| <dbrowend> heitml * .
Format::= html | text | quoted | heitml | hstv | furl | Expr .
ActualParameterlist::= ( [ ParameterName = ] Expr ) * .
FormalParameterlist::= ( ParameterName [= Expr ]  | * ParameterName  | ** ParameterName
      | @ VariableName  | @ this
  ) * [ ... ] .
Expr::= Expr + Expr | Expr - Expr | Expr * Expr | Expr / Expr | Expr % Expr
| - Expr | ! Expr
| Expr == Expr | Expr != Expr
| Expr && Expr | Expr || Expr
| Expr < Expr | Expr &lt Expr | Expr &lt; Expr
| Expr <= Expr | Expr &le Expr | Expr &le; Expr
| Expr &gt Expr | Expr &gt; Expr
| Expr &ge Expr | Expr &ge; Expr
| ( Expr )
| Expr [ Expr ]
| Expr . FieldName
| Expr = Expr
| Expr , Expr
| Expr . MethodName ( ActualParameterList )
| Expr [ Expr ] ( ActualParameterList )
| FunctionName ( ActualParameterList )
| IntegerConst | RealConst | StringConst
| true | false | emptytuple | null | this | parent | creator
| VariableName.
Operator precedence: , = || && == != < <= &ge &gt &le &lt + - * / % unary - ! . [ ] ( ).
VariableName::= Identifier .
FieldName::= Identifier .
ParameterName::= Identifier .
FunctionName::= Identifier .
MethodName::= Identifier .
ClassName::= Identifier .

This page was dynamically generated by the web application development tool RADpage of H.E.I.

Selected blog articles : 3D Objects on HTML pages, CSS Transition Visibility, and CSS Transition Display.


© 1996-2024 H.E.I. All Rights Reserved.



Homepage
Intro/Features
Component Guide
Programming
  Language Guide
  Language Ref.
    General Design
    Lexical Structure
    Expressions
    Objects
    Methods
    Classes
    heitml Tags
    heitml Functions
    Advanced Functions
    Database Access
    Global Variables
    Form Fields
    Server Variables
    Sessions
    heitml Syntax
  Component Ref.
  Class Library
  User Components
  Tutorial
  New Features
  heitml 1
User Guide
Services
Privacy
Datenschutz
 
Contact / Impressum